ShaderLab構文：Blending

Blendingは透過のカラー作成に使用します。

グラフィックスがレンダリングされて,さらに全てのシェーダが実行されて,全てのテクスチャが適用されると,画面にピクセルが描画されます。すでに存在しているピクセルに対して,どのように合成するかはブレンディングで制御されます。

構文

Blend Off : ブレンディングを無効にします。

Blend SrcFactor DstFactor : ブレンディングを有効にして,設定をします。生成されたカラーは SrcFactor に乗算されます。画面にすでにあるカラーは DstFactor を乗算して,2つを合成します。

Blend SrcFactor DstFactor, SrcFactorA DstFactorA : 上記と同様ですが,アルファチャネルをブレンディングするのに,異なる要素を使用します。

BlendOp BlendOp: ブレンディングされたカラーを使用する代わりに別の処理を行います。

Blend操作

次のブレンド操作を使用することが出来ます:

Blend係数

全てのプロパティは Blend コマンドの SrcFactorとDstFactorの両方で有効です。　__Source__ は計算された色を指し, Destination は既に設定されたスクリーン上の色となります。もし__BlendOp__がlogical演算を使用している場合ブレンド係数は無視されます。

詳細

次がもっとも一般的なプレンディングのタイプです：

Blend SrcAlpha OneMinusSrcAlpha // Alpha blending
Blend One One // Additive
Blend OneMinusDstColor One // Soft Additive
Blend DstColor Zero // Multiplicative
Blend DstColor SrcColor // 2x Multiplicative

例

次は簡潔な例のシェーダで,画面にすでにあるものに,テクスチャを加えます。

Shader "Simple Additive" {
    Properties {
        _MainTex ("Texture to blend", 2D) = "black" {}
    }
    SubShader {
        Tags { "Queue" = "Transparent" }
        Pass {
            Blend One One
            SetTexture [_MainTex] { combine texture }
        }
    }
}

さらに複雑な例,グラスです。これは2パスのシェーダとなります：

1. 最初のパスで,照らされてアルファブレンディングされたテクスチャを画面にレンダリングします。アルファチャネルで透過性を決定します。
2. 2つめのパスで,アルファブレンディングされたウィンドウの上に,Additiveの透過性を使用して,反射キューブマップをレンダリングします。

Shader "Glass" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)
        _MainTex ("Base (RGB) Transparency (A)", 2D) = "white" {}
        _Reflections ("Base (RGB) Gloss (A)", Cube) = "skybox" { TexGen CubeReflect }
    }
    SubShader {
        Tags { "Queue" = "Transparent" }
        Pass {
            Blend SrcAlpha OneMinusSrcAlpha
            Material {
                Diffuse [_Color]
            }
            Lighting On
            SetTexture [_MainTex] {
                combine texture * primary double, texture * primary
            }
        }
        Pass {
            Blend One One
            Material {
                Diffuse [_Color]
            }
            Lighting On
            SetTexture [_Reflections] {
                combine texture
                Matrix [_Reflection]
            }
        }
    }
}