内置渲染管线中的阴影投射着色器示例

我们的着色器目前既不能接受也不能投射阴影。让我们先实现阴影投射。

为了投射阴影，着色器必须在其任何子着色器或任何回退中具有 ShadowCaster 通道类型。ShadowCaster 通道用于将对象渲染到阴影贴图中，通常它非常简单：顶点着色器只需要估算顶点位置，片元着色器几乎不执行任何操作。阴影贴图只是深度缓冲区，因此即使是片元着色器输出的颜色也无关紧要。

这意味着对于许多着色器，阴影投射物通道几乎完全相同（除非对象具有基于自定义顶点着色器的变形，或者具有 Alpha 镂空/半透明部分）。最简单的捕捉方法是使用着色器命令 UsePass：

Pass
{
    // regular lighting pass
}
// pull in shadow caster from VertexLit built-in shader
UsePass "Legacy Shaders/VertexLit/SHADOWCASTER"

但我们在这里是为了学习，所以让我们通过“手动”方式实现相同效果。为了缩短代码长度，我们已经将光照通道（“ForwardBase”）替换为仅执行无纹理环境光的代码。在它下面，有一个“ShadowCaster”通道，让对象能够支持阴影投射。

Shader "Lit/Shadow Casting"
{
    SubShader
    {
        // very simple lighting pass, that only does non-textured ambient
        Pass
        {
            Tags {"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            struct v2f
            {
                fixed4 diff : COLOR0;
                float4 vertex : SV_POSITION;
            };
            v2f vert (appdata_base v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                half3 worldNormal = UnityObjectToWorldNormal(v.normal);
                // only evaluate ambient
                o.diff.rgb = ShadeSH9(half4(worldNormal,1));
                o.diff.a = 1;
                return o;
            }
            fixed4 frag (v2f i) : SV_Target
            {
                return i.diff;
            }
            ENDCG
        }

        // shadow caster rendering pass, implemented manually
        // using macros from UnityCG.cginc
        Pass
        {
            Tags {"LightMode"="ShadowCaster"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_shadowcaster
            #include "UnityCG.cginc"

            struct v2f { 
                V2F_SHADOW_CASTER;
            };

            v2f vert(appdata_base v)
            {
                v2f o;
                TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
                return o;
            }

            float4 frag(v2f i) : SV_Target
            {
                SHADOW_CASTER_FRAGMENT(i)
            }
            ENDCG
        }
    }
}

现在下方有一个平面，使用常规的内置漫射着色器，因此我们可以看到我们的阴影生效（请记住，我们当前的着色器还不支持 接受 阴影！）。

我们使用了 #pragma multi_compile_shadowcaster 指令。这会导致着色器被编译为多个变体，并为每个变体定义了不同的预处理器宏（有关详细信息，请参阅多个着色器变体页面）。渲染到阴影贴图时，点光源与其他光源类型需要着色器代码略有不同，这就是需要此指令的原因。