URP のシェーダーでの法線ベクトルの可視化

この例の Unity シェーダーは、メッシュ上に法線ベクトル値を可視化します。

URP の基本的な Unlit シェーダーセクションの Unity シェーダーソースファイルを使用し、ShaderLab コードに以下の変更を加えます。

1. この例の頂点シェーダー用の入力構造体である struct Attributes で、各頂点の法線ベクトルが含まれる変数を宣言します。

   struct Attributes
   {
       float4 positionOS   : POSITION;
       // Declaring the variable containing the normal vector for each vertex.
       half3 normal        : NORMAL;
   };
   

2. この例のフラグメントシェーダー用の入力構造体である struct Varyings で、各フラグメントの法線ベクトル値を格納するための変数を宣言します。

   struct Varyings
   {
       float4 positionHCS  : SV_POSITION;
       // The variable for storing the normal vector values.
       half3 normal        : TEXCOORD0;
   };
   

   この例では、法線ベクトルの 3 つの成分を各フラグメントの RGB カラー値として使用します。

3. メッシュ上に法線ベクトル値をレンダリングするため、以下のコードをフラグメントシェーダーとして使用します。

   half4 frag(Varyings IN) : SV_Target
   {
       half4 color = 0;
       color.rgb = IN.normal;
       return color;
   }
   

4. Unity によってメッシュ上に法線ベクトル値がレンダリングされます。

   

   カプセルの一部が黒色になっています。これは、それらの点における法線ベクトルの 3 つの成分すべてが負だからです。次のステップでは、そうした領域の値もレンダリングする方法を示します。

5. 負の法線ベクトル成分をレンダリングするには、圧縮手法を使用します。法線成分値の範囲 (-1..1) を色値の範囲 (0..1) に圧縮するには、以下の行を

   color.rgb = IN.normal;
   

   以下の行に変更します。

   color.rgb = IN.normal * 0.5 + 0.5;
   

これで Unity によってメッシュ上に法線ベクトル値が色としてレンダリングされます。

以下は、この例の完成した ShaderLab コードです。

// This shader visuzlizes the normal vector values on the mesh.
Shader "Example/URPUnlitShaderNormal"
{
    Properties
    { }

    SubShader
    {
        Tags { "RenderType" = "Opaque" "RenderPipeline" = "UniversalPipeline" }

        Pass
        {
            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

            struct Attributes
            {
                float4 positionOS   : POSITION;
                // Declaring the variable containing the normal vector for each
                // vertex.
                half3 normal        : NORMAL;
            };

            struct Varyings
            {
                float4 positionHCS  : SV_POSITION;
                half3 normal        : TEXCOORD0;
            };

            Varyings vert(Attributes IN)
            {
                Varyings OUT;
                OUT.positionHCS = TransformObjectToHClip(IN.positionOS.xyz);
                // Use the TransformObjectToWorldNormal function to transform the
                // normals from object to world space. This function is from the
                // SpaceTransforms.hlsl file, which is referenced in Core.hlsl.
                OUT.normal = TransformObjectToWorldNormal(IN.normal);
                return OUT;
            }

            half4 frag(Varyings IN) : SV_Target
            {
                half4 color = 0;
                // IN.normal is a 3D vector. Each vector component has the range
                // -1..1. To show all vector elements as color, including the
                // negative values, compress each value into the range 0..1.
                color.rgb = IN.normal * 0.5 + 0.5;
                return color;
            }
            ENDHLSL
        }
    }
}