シェーダーでの 3D テクスチャのサンプリング

カスタムシェーダーで 3D テクスチャを使用するには、以下を使用できます。

• 3D マテリアルプロパティ宣言。3D テクスチャプロパティを追加します。例：_MainTex ("Example 3D texture", 3D) = "white" {};
• sampler3D サンプラー状態。3D テクスチャをシェーダー入力として使用します。例：sampler3D _MainTex;
• tex3D HLSL メソッド。3D テクスチャをサンプリングします。例：float4 color = tex3D(_MainTex, float3(0.5f, 0.5f, 0.5f));

例

以下は、3D テクスチャをサンプリングして半透明のボリュームとして描画するために、レイマーチングを使用するシェーダーの例です。

この例を使用するには、以下のステップに従います。

1. Project ウィンドウで、Add > Shader > Unlit Shader を使用して新しい基本シェーダーを作成します。
2. シェーダーコードをサンプルコードに置き換えます。
3. Project ウィンドウでシェーダーを右クリックし、Create > Material を選択してシェーダーから新しいマテリアルを作成します。
4. 3D テクスチャをインポートまたは作成します。例えば、スクリプトで 3D テクスチャを作成する ページのサンプルコードを使用します。
5. 3D テクスチャアセットを Project ウィンドウからマテリアルの Texture 3D プロパティにドラッグします。
6. ゲームオブジェクトにマテリアルをアタッチします。

Shader "Unlit/VolumeShader"
{
    Properties
    {
        _MainTex ("Texture", 3D) = "white" {}
        _Alpha ("Alpha", float) = 0.02
        _StepSize ("Step Size", float) = 0.01
    }
    SubShader
    {
        Tags { "Queue" = "Transparent" "RenderType" = "Transparent" }
        Blend One OneMinusSrcAlpha
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            // Maximum number of raymarching samples
            #define MAX_STEP_COUNT 128

            // Allowed floating point inaccuracy
            #define EPSILON 0.00001f

            struct appdata
            {
                float4 vertex : POSITION;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 objectVertex : TEXCOORD0;
                float3 vectorToSurface : TEXCOORD1;
            };

            sampler3D _MainTex;
            float4 _MainTex_ST;
            float _Alpha;
            float _StepSize;

            v2f vert (appdata v)
            {
                v2f o;

                // Vertex in object space. This is the starting point for the raymarching.
                o.objectVertex = v.vertex;

                // Calculate vector from camera to vertex in world space
                float3 worldVertex = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.vectorToSurface = worldVertex - _WorldSpaceCameraPos;

                o.vertex = UnityObjectToClipPos(v.vertex);
                return o;
            }

            float4 BlendUnder(float4 color, float4 newColor)
            {
                color.rgb += (1.0 - color.a) * newColor.a * newColor.rgb;
                color.a += (1.0 - color.a) * newColor.a;
                return color;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                // Start raymarching at the front surface of the object
                float3 rayOrigin = i.objectVertex;

                // Use vector from camera to object surface to get ray direction
                float3 rayDirection = mul(unity_WorldToObject, float4(normalize(i.vectorToSurface), 1));

                float4 color = float4(0, 0, 0, 0);
                float3 samplePosition = rayOrigin;

                // Raymarch through object space
                for (int i = 0; i < MAX_STEP_COUNT; i++)
                {
                    // Accumulate color only within unit cube bounds
                    if(max(abs(samplePosition.x), max(abs(samplePosition.y), abs(samplePosition.z))) < 0.5f + EPSILON)
                    {
                        float4 sampledColor = tex3D(_MainTex, samplePosition + float3(0.5f, 0.5f, 0.5f));
                        sampledColor.a *= _Alpha;
                        color = BlendUnder(color, sampledColor);
                        samplePosition += rayDirection * _StepSize;
                    }
                }

                return color;
            }
            ENDCG
        }
    }
}

スクリプトで 3D テクスチャを作成する ページから 3D テクスチャのサンプルシェーダーを使用した場合に Unity がレンダリングするボリューム。

追加リソース

• シェーダーの作成
• ShaderLab: マテリアルプロパティの定義
• サンプラー状態