頂点プログラムへ頂点データの流し込み

For Cg/HLSL vertex programs, the Mesh vertex data is passed as inputs to the vertex shader function. Each input needs to have a semantic specified for it: for example, POSITION input is the vertex position, and NORMAL is the vertex normal.

しばしば、頂点のデータ入力は 1 つずつ記述されず、構造体で宣言されます。よく使用される頂点構造体は、 UnityCG.cginc include ファイル で定義され、たいてい、それを使えば十分です。それらの構造体は以下の通りです。

• appdata_base: 位置、法線および 1 つのテクスチャ座標で構成されます。
• appdata_tan: 位置、接線、法線および 1 つのテクスチャ座標で構成されます。
• appdata_full: 位置、接線、法線、4 つのテクスチャ座標および色で構成されています。

例: このシェーダーは、その法線に基づいて、メッシュに色を付け、頂点プログラム入力として、appdata_base を使用します。

Shader "VertexInputSimple" {
    SubShader {
        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
         
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
            };
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color.xyz = v.normal * 0.5 + 0.5;
                o.color.w = 1.0;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target { return i.color; }
            ENDCG
        }
    } 
}

さまざまな頂点データにアクセスするには、頂点の構造体を自身で宣言するか、頂点シェーダーに入力パラメーターを加える必要があります。頂点のデータは Cg/HLSL セマンティック によって識別されます。そして、以下のリストに準ずる必要があります。

• POSITION は頂点位置、一般的には float3 か float4 です。
• NORMAL は頂点法線で、一般的には float3 です。
• TEXCOORD0 は、第 1 の UV 座標で、一般的に、float2, float3, float4 です。
• TEXCOORD1, TEXCOORD2, TEXCOORD3 は、それぞれ第 2、第 3、第 4 の UV 座標です。
• TANGENT は、（ノーマルマッピングで使用される）接線ベクトルで、一般的には、 float4 です。
• COLOR は、頂点ごとの色で、一般的には、 float4 です。

メッシュデータが、頂点シェーダー入力で必要とされるよりも少ない数の要素しか持たない場合、デフォルトで 1 に設定されている .w 要素を除いて残りの部分をゼロで埋めます。例えば、メッシュテクスチャ座標は、しばしば、x と y コンポーネントしか持たない 2D ベクトルです。頂点シェーダーが TEXCOORD0 セマンティックで float4 の入力を宣言する場合、その頂点シェーダーによって受け取る値には (x,y,0,1) が含まれます。

これらのテクニックを使って、ビルトインレンダーパイプラインで頂点データを視覚化する例は、頂点データの視覚化 を参照してください。