向顶点程序提供顶点数据

For Cg/HLSL vertex programs, the Mesh vertex data is passed as inputs to the vertex shader function. Each input needs to have a semantic specified for it: for example, POSITION input is the vertex position, and NORMAL is the vertex normal.

通常，顶点数据输入在结构中声明，而不是 逐个列出。在 UnityCG.cginc include 文件中 定义了几个常用的顶点结构，在大多数情况下， 仅使用它们就足够了。这些结构为：

• appdata_base：位置、法线和一个纹理坐标。
• appdata_tan：位置、切线、法线和一个纹理坐标。
• appdata_full：位置、切线、法线、四个纹理坐标和颜色。

示例：以下着色器根据法线为网格着色，并使用 appdata_base 作为顶点程序输入：

Shader "VertexInputSimple" {
    SubShader {
        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
         
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
            };
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color.xyz = v.normal * 0.5 + 0.5;
                o.color.w = 1.0;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target { return i.color; }
            ENDCG
        }
    } 
}

要访问不同的顶点数据，您需要自己声明 顶点结构，或者将输入参数添加到 顶点着色器。顶点数据由 Cg/HLSL 语义标识，并且必须来自 以下列表：

• POSITION 是顶点位置，通常为 float3 或 float4。
• NORMAL 是顶点法线，通常为 float3。
• TEXCOORD0 是第一个 UV 坐标，通常为 float2、float3 或 float4。
• TEXCOORD1、TEXCOORD2 和 TEXCOORD3 分别是第 2、第 3 和第 4 个 UV 坐标。
• TANGENT 是切线矢量（用于法线贴图），通常为 float4。
• COLOR 是每顶点颜色，通常为 float4。

当网格数据包含的分量少于顶点着色器输入所需 的分量时，其余部分用零填充，但默认值为 1 的 .w 分量除外。例如，网格纹理坐标 通常是仅包含 x 和 y 分量的 2D 矢量。如果 顶点着色器使用 TEXCOORD0 语义声明一个 float4 输入，则 顶点着色器接收的值将包含 (x,y,0,1)。

有关使用这些技术在内置渲染管线中可视化顶点数据的示例，请参阅可视化顶点数据。