Version: 2020.3
ShaderLab command: Offset
ShaderLab command: UsePass

ShaderLab command: Stencil

Configures settings relating to the stencil bufferA memory store that holds an 8-bit per-pixel value. In Unity, you can use a stencil buffer to flag pixels, and then only render to pixels that pass the stencil operation. More info
See in Glossary
on the GPU.

The stencil buffer stores an 8-bit integer value for each pixelThe smallest unit in a computer image. Pixel size depends on your screen resolution. Pixel lighting is calculated at every screen pixel. More info
See in Glossary
in the frame buffer. Before executing the fragment shaderA program that runs on the GPU. More info
See in Glossary
for a given pixel, the GPU can compare the current value in the stencil buffer against a given reference value. This is called a stencil test. If the stencil test passes, the GPU performs the depth test. If the stencil test fails, the GPU skips the rest of the processing for that pixel. This means that you can use the stencil buffer as a mask to tell the GPU which pixels to draw, and which pixels to discard.

You would typically use the stencil buffer for special effects such as portals or mirrors. Additionally, the stencil buffer is sometimes used when renderingThe process of drawing graphics to the screen (or to a render texture). By default, the main camera in Unity renders its view to the screen. More info
See in Glossary
hard shadows, or constructive solid geometry (CSG).

Render pipeline compatibility

Feature name Built-in Render Pipeline Universal Render Pipeline (URP) High Definition Render Pipeline (HDRP) Custom SRP
Stencil Yes Yes Yes Yes

Usage

This command makes a change to the render state. Use it in a Pass block to set the render state for that Pass, or use it in a SubShader block to set the render state for all Passes in that SubShader.

You can use the Stencil command to do two different things: to configure the stencil test, and to configure what the GPU writes to the stencil buffer. You can do both of these things in the same command, but the most common use case is to create one Shader object that masks out areas of the screen that other Shader objects cannot draw to. To do this, you need to configure the first Shader object to always pass the stencil test and write to the stencil buffer, and configurethe others to perform a stencil test and not write to the stencil buffer.

Use the Ref, ReadMask, and Comp parameters to configure the stencil test. Use the Ref, WriteMask, Pass, Fail, and ZFail parameters to configure the stencil write operation.

The stencil test equation is:

(ref & readMask) comparisonFunction (stencilBufferValue & readMask)
Signature Example syntax Function
Stencil
{
    Ref <ref>
    ReadMask <readMask>
    WriteMask <writeMask>
    Comp <comparisonOperation>
    Pass <passOperation>
    Fail <failOperation>
    ZFail <zFailOperation>
    CompBack <comparisonOperationBack>
    PassBack <passOperationBack>
    FailBack <failOperationBack>
    ZFailBack <zFailOperationBack>
    CompFront <comparisonOperationFront>
    PassFront <passOperationFront>
    FailFront <failOperationFront>
    ZFailFront <zFailOperationFront>
    }

Note that all parameters are optional.
Stencil
{
    Ref 2
    Comp equal
    Pass keep
    ZFail decrWrap
    }
Configures the stencil buffer according to the given parameters.

Valid parameter values

Parameter Value Function
ref An integer. Range 0 through 255. Default is 0. The reference value.

The GPU compares the current contents of the stencil buffer against this value, using the operation defined in comparisonOperation.

This value is masked with readMask or writeMask, depending on whether a read or a write operation is occurring.

The GPU can also write this value to the stencil buffer, if Pass, Fail or ZFail have a value of Replace.
readMask An integer. Range 0 through 255. Default is 255. The GPU uses this value as a mask when it performs the stencil test.

See above for the stencil test equation.
writeMask An integer. Range 0 through 255. Default is 255. The GPU uses this value as a mask when it writes to the stencil buffer.

Note that, like other masks, it specifies which bits are included in the operation. For example, a value of 0 means that no bits are included in the write operation, not that the stencil buffer receives a value of 0.
comparisonOperation A comparison operation. See Comparison operation values for valid values. Default is Always. The operation that the GPU performs for the stencil test for all pixels.

This defines the operation for all pixels, regardless of facing. If this is defined in addition to comparisonOperationBack and comparisonOperationFront, this value overrides them.
passOperation A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel pases both the stencil test and the depth test.

This defines the operation for all pixels, regardless of facing. If this is defined in addition to passOperationBack and passOperationFront, this value overrides them.
failOperation A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel fails the stencil test.

This defines the operation for all pixels, regardless of facing. If this is defined in addition to failOperationBack and failOperationFront, this value overrides them.
zFailOperation A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel passes the stencil test, but fails the depth test.

This defines the operation for all pixels, regardless of facing. If this is defined in addition to zFailOperation and zFailOperation, this value overrides them.
comparisonOperationBack A comparison operation. See Comparison operation values for valid values. Default is Always. The operation that the GPU performs for the stencil test.

This defines the operation for back-facing pixels only. If comparisonOperation is defined, that value overrides this one.
passOperationBack A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel pases both the stencil test and the depth test.

This defines the operation for back-facing pixels only. If passOperation is defined, that value overrides this one.
failOperationBack A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel fails the stencil test.

This defines the operation for back-facing pixels only. If failOperation is defined, that value overrides this one.
zFailOperationBack A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel passes the stencil test, but fails the depth test.

This defines the operation for back-facing pixels only. If zFailOperation is defined, that value overrides this one.
comparisonOperationFront A comparison operation. See Comparison operation values for valid values. Default is Always. The operation that the GPU performs for the stencil test.

This defines the operation for front-facing pixels only. If comparisonOperation is defined, that value overrides this one.
passOperationFront A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel pases both the stencil test and the depth test.

This defines the operation for front-facing pixels only. If passOperation is defined, that value overrides this one.
failOperationFront A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel fails the stencil test.

This defines the operation for front-facing pixels only. If failOperation is defined, that value overrides this one.
zFailOperationFront A stencil operation. See Stencil operation values for valid values. Default is Keep. The operation that the GPU performs on the stencil buffer when a pixel passes the stencil test, but fails the depth test.

This defines the operation for front-facing pixels only. If zFailOperation is defined, that value overrides this one.

Comparison operation values

In C#, these values are represented by the Rendering.CompareFunction enum.

Value Corresponding integer value in Rendering.CompareFunction enum Function
Never 0 Never render pixels.
Less 1 Render pixels when their reference value is less than the current value in the stencil buffer.
Equal 2 Render pixels when their reference value is equal to the current value in the stencil buffer.
LEqual 3 Render pixels when their reference value is less than or equal to the current value in the stencil buffer.
NotEqual 4 Render pixels when their reference value differs from the current value in the stencil buffer.
GEqual 5 Render pixels when their reference value is greater than or equal to the current value in the stencil buffer.
Always 6 Always render pixels.

Stencil operation values

In C#, these values are represented by the Rendering.Rendering.StencilOp enum.

Value Corresponding integer value in Rendering.StencilOp enum Function
Keep 0 Keep the current contents of the stencil buffer.
Zero 1 Write 0 into the stencil buffer.
Replace 2 Write the reference value into the buffer.
IncrSat 3 Increment the current value in the buffer. If the value is 255 already, it stays at 255.
DecrSat 4 Decrement the current value in the buffer. If the value is 0 already, it stays at 0.
Invert 5 Negate all the bits of the current value in the buffer.
IncrWrap 7 Increment the current value in the buffer. If the value is 255 already, it becomes 0.
DecrWrap 8 Decrement the current value in the buffer. If the value is 0 already, it becomes 255.

Examples

Shader "Examples/CommandExample"
{
    SubShader
    {
         // The rest of the code that defines the SubShader goes here.

        Pass
        {    
             // All pixels in this Pass will pass the stencil test and write a value of 2 to the stencil buffer
             // You would typically do this if you wanted to prevent subsequent shaders from drawing to this area of the render target or restrict them to render to this area only
             Stencil
             {
                 Ref 2
                 Comp Always
                 Pass Replace
             }            

             // The rest of the code that defines the Pass goes here.
        }
    }
}

This example code demonstrates the syntax for using this command in a SubShader block.

Shader "Examples/CommandExample"
{
    SubShader
    {
             // All pixels in this SubShader pass the stencil test only if the current value of the stencil buffer is less than 2
             // You would typically do this if you wanted to only draw to areas of the render target that were not "masked out"
             Stencil
             {
                 Ref 2
                 Comp Less
             }  

         // The rest of the code that defines the SubShader goes here.        

        Pass
        {    
              // The rest of the code that defines the Pass goes here.
        }
    }
}
ShaderLab command: Offset
ShaderLab command: UsePass