Version: 2019.4
ShaderLab: SubShader LOD value
Visual Studio로 DirectX 11/12 셰이더 디버깅

Using texture arrays in shaders

Similar to regular 2D textures (Texture2D class, sampler2D in shaders), cube maps (Cubemap class, samplerCUBE in shaders), and 3D textures (Texture3D class, sampler3D in shaders), Unity also supports 2D texture arrays.

텍스처 배열은 모든 플랫폼에서 작동하지는 않으므로 셰이더에서 텍스처 배열에 액세스하려면 적절한 컴파일 타겟(compilation target) 또는 기능 요구 사항을 사용해야 합니다. 텍스처 배열을 지원하는 최소 셰이더 모델 컴파일 타겟은 3.5이고 기능 이름은 2darray입니다.

텍스처 배열을 선언하고 샘플링하려면 다음 매크로를 사용해야 합니다.

  • UNITY_DECLARE_TEX2DARRAY(name)는 HLSL 코드 내에 텍스처 배열 샘플러 변수를 선언합니다.
  • UNITY_SAMPLE_TEX2DARRAY(name,uv)는 float3 UV가 있는 텍스처 배열을 샘플링합니다. 좌표의 z 컴포넌트는 배열 요소 인덱스입니다.
  • UNITY_SAMPLE_TEX2DARRAY_LOD(name,uv,lod)는 명시적 밉맵 레벨이 있는 텍스처 배열을 샘플링합니다.

예제

다음 셰이더 예제에서는 오브젝트 공간 버텍스 포지션을 좌표로 사용하여 텍스처 배열을 샘플링합니다.

Shader "Example/Sample2DArrayTexture"
{
    Properties
    {
        _MyArr ("Tex", 2DArray) = "" {}
        _SliceRange ("Slices", Range(0,16)) = 6
        _UVScale ("UVScale", Float) = 1.0
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // texture arrays are not available everywhere,
            // only compile shader on platforms where they are
            #pragma require 2darray
            
            #include "UnityCG.cginc"

            struct v2f
            {
                float3 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            float _SliceRange;
            float _UVScale;

            v2f vert (float4 vertex : POSITION)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, vertex);
                o.uv.xy = (vertex.xy + 0.5) * _UVScale;
                o.uv.z = (vertex.z + 0.5) * _SliceRange;
                return o;
            }
            
            UNITY_DECLARE_TEX2DARRAY(_MyArr);

            half4 frag (v2f i) : SV_Target
            {
                return UNITY_SAMPLE_TEX2DARRAY(_MyArr, i.uv);
            }
            ENDCG
        }
    }
}

참고 항목


  • 2018–03–20 페이지 수정됨
  • Unity 2018.1에서 셰이더 #pragma 지시문 추가됨
ShaderLab: SubShader LOD value
Visual Studio로 DirectX 11/12 셰이더 디버깅