Checkerboard ノード

説明

入力 UV に基づいて、入力 Color A の色と入力 Color B の色で構成されたチェッカーボード模様を生成します。チェッカーボードのスケールは入力 Frequency によって定義されます。

ポート

Name	Direction	タイプ	バインディング	説明
UV	入力	Vector 2	UV	入力 UV 値
Color A	入力	Color RGB	なし	チェッカーボードの模様の 1 つ目の色
Color B	入力	Color RGB	なし	チェッカーボードの模様の 2 つ目の色
Frequency	入力	Vector 2	なし	軸ごとのチェッカーボード模様のスケール
Out	出力	Vector 2	なし	出力 UV 値

生成されるコードの例

以下のサンプルコードは、このノードの出力の一例を示したものです。

void Unity_Checkerboard_float(float2 UV, float3 ColorA, float3 ColorB, float2 Frequency, out float3 Out)
{
    UV = (UV.xy + 0.5) * Frequency;
    float4 derivatives = float4(ddx(UV), ddy(UV));
    float2 duv_length = sqrt(float2(dot(derivatives.xz, derivatives.xz), dot(derivatives.yw, derivatives.yw)));
    float width = 1.0;
    float2 distance3 = 4.0 * abs(frac(UV + 0.25) - 0.5) - width;
    float2 scale = 0.35 / duv_length.xy;
    float freqLimiter = sqrt(clamp(1.1f - max(duv_length.x, duv_length.y), 0.0, 1.0));
    float2 vector_alpha = clamp(distance3 * scale.xy, -1.0, 1.0);
    float alpha = saturate(0.5f + 0.5f * vector_alpha.x * vector_alpha.y * freqLimiter);
    Out = lerp(ColorA, ColorB, alpha.xxx);
}